Key features:
function with constants, diamond symbol, text within image ("labels"), text and symbol at specific locations, error bars, plot function only in specified range, logarithmic scale ("logscale") for only one axis, publication quality
This image is Fig. 2 from my fourth publication.
This figure has two main interesting features:
The diamond and "CP" label are at specific (Temperature, Pressure) locations.
The black line is a smooth, analytic function, defined on a range greater than [375, 700]; however, I have terminated/truncated the plotting of the function at the spot marked "CP."
reset
set terminal pngcairo truecolor nocrop enhanced font "arial,80" size 3078,2303 ## good ratio for publication: 1.336
#set encoding utf8
set output "ManuscriptV6_Figure_2_v2.png" ## output filename
unset grid ## alternatively, use "with lines" after "plot"
set samples 10000 ## default=100... improves smoothness
set border 15 lw 9
set tics scale 1.25
set bars 0.5 ## errorbar cap width {small | large | fullwidth | <size>}
#set lmargin 5
#set lmargin at screen 0.175
#set bmargin at screen 0.175
set xlabel "Temperature (K)" offset 0,.5
set xrange [375:700] ## options: "[min:max]" , "[:]" is "perfect" range,
#set format x "%1.1f" ## "%N.Mf" has N total digits, with M after the decimal.
set xtics 300,100,1000 offset -.25,.25 #out nomirror ## this is the spacing between tics on the x-axis
set mxtics 4 ## frequency of the MINOR x-tics;
set ylabel "Pressure (bar)" offset 3.,0
set yrange [.11:280]
#set format y "%1.1f" ## "%N.Mf" has N total digits, with M after the decimal.
#set ytic 0,1000,10000 offset .75,-.1 nomirror ## spacing between tics on the y-axis
set ytic offset .25,0 #nomirror ## spacing between tics on the y-axis
set mytics 5 ## frequency of the MINOR x-tics;
set key spacing 1.2 ## vertical spacing between legend lines.
set key samplen .5 ## length of line sample shown in legend.
#set key maxrows 1
#set key maxcolumns 1
set key nobox
set key at graph .35,.95 ## where to put legend: left right center top bottom center
#set key font "arial,60"
Tcd = 674.561
Tca = Tcd
wagner_BLYPSP(x) = lnpc + (Tca/x)*( aa*(1-x/Tca) + bb*(1-x/Tca)**1.5 + cc*(1-x/Tca)**3 + dd*(1-x/Tca)**6 )
lnpc = 4.99
aa = -8.69748
bb = 1.03485
cc = -0.411408
dd = -53.3456
set logscale y
set label "CP" at 674.561,80 center
set pointsize 5
plot \
exp(wagner_BLYPSP(x)) w lines lc rgb "black" lw 10 title "fitted",\
"dens_pres_vs_T.dat" u 1:9:11 w yerrorbars pt 7 lc rgb "red" lw 10 title "simulated",\
"< echo '674.561 146.9364' " w points pt 13 lc rgb "black" lw 10 title ""
unset logscale y
##################
# pointtype ("pt")
# 0 = none
# 1 = horz.line
# 2 = X
# 3 = X & horz.line
# 4 = open box
# 5 = closed box
# 6 = open circle
# 7 = closed circ.
# 8 = open up triang.
# 9 = closed up triang.
# 10= open down triang.
# 11= closed down triang.
# 12= open diamond
# 13= solid diamond
# linetype ("lt")
# -1 = black
# 0 = grey dotted
# 1 = purple
# 2 = green
# 3 = sky blue
# 4 = orange
# 5 = yellow
# 6 = navy blue
# 7 = red
# \305 = Angstrom
# {/Symbol *} = Greek *